Este exemplo demonstra uma técnica para calibrar um sensor de entrada. O Arduino faz leituras do sensor por cinco segundos durante a inicialização, e acompanha os valores mais altos e mais baixos que recebe. As leituras do sensor durante estes primeiros cinco segundos vão definir os valores mínimos e máximos esperados durante o loop.

Componentes necessários:

  • Arduino
  • 1 LED
  • 1 Sensor de luminosidade (LDR 5mm)
  • 1 resistor 330Ω
  • 1 resistor 10kΩ
  • Protoboard
  • Jumpers
  • 1 Cabo USB

Circuito

Conecte o LED no pino digital 9 com um resistor de 330Ω. Conecte o sensor de luminosidade na entrada de 5V e na entrada analógica 0 com o resistor de 10kΩ com o terra de referência.

Arduino Exemplos: Calibração

Esquema

Código

Antes da instalação, você define os valores iniciais para o mínimo e o máximo da seguinte maneira:

int sensorMin = 1023;        // minimum sensor value
int sensorMax = 0;           // maximum sensor value


Isso pode soar contraditório, mas inicialmente você define um mínimo elevado e faz a leitura para qualquer valor abaixo disso, e salva como novo mínimo. Da mesma forma, você define um máximo baixo e faz a leitura para qualquer valor acima disso, e salva como novo máximo:

// calibrate during the first five seconds
 while (millis() < 5000) {
   sensorValue = analogRead(sensorPin);

   // record the maximum sensor value
   if (sensorValue > sensorMax) {
     sensorMax = sensorValue;
   }

   // record the minimum sensor value
   if (sensorValue < sensorMin) {
     sensorMin = sensorValue;
   }
 }

 
Dessa forma, qualquer leitura que você tomar pode ser mapeada para o intervalo entre este mínimo e máximo da seguinte maneira:

// apply the calibration to the sensor reading

sensorValue = map(sensorValue, sensorMin, sensorMax, 0, 255);


Aqui segue o código completo:

/*
  Calibration
 
 Demonstrates one technique for calibrating sensor input.  The
 sensor readings during the first five seconds of the sketch
 execution define the minimum and maximum of expected values
 attached to the sensor pin.
 
 The sensor minimum and maximum initial values may seem backwards.
 Initially, you set the minimum high and listen for anything
 lower, saving it as the new minimum. Likewise, you set the
 maximum low and listen for anything higher as the new maximum.
 
 The circuit:
 * Analog sensor (potentiometer will do) attached to analog input 0
 * LED attached from digital pin 9 to ground
 
 created 29 Oct 2008
 By David A Mellis
 modified 30 Aug 2011
 By Tom Igoe
 
 http://arduino.cc/en/Tutorial/Calibration
 
 This example code is in the public domain.
 
 */

// These constants won't change:
const int sensorPin = A0;    // pin that the sensor is attached to
const int ledPin = 9;        // pin that the LED is attached to

// variables:
int sensorValue = 0;         // the sensor value
int sensorMin = 1023;        // minimum sensor value
int sensorMax = 0;           // maximum sensor value


void setup() {
  // turn on LED to signal the start of the calibration period:
  pinMode(13, OUTPUT);
  digitalWrite(13, HIGH);

  // calibrate during the first five seconds
  while (millis() < 5000) {
    sensorValue = analogRead(sensorPin);

    // record the maximum sensor value
    if (sensorValue > sensorMax) {
      sensorMax = sensorValue;
    }

    // record the minimum sensor value
    if (sensorValue < sensorMin) {
      sensorMin = sensorValue;
    }
  }

  // signal the end of the calibration period
  digitalWrite(13, LOW);
}

void loop() {
  // read the sensor:
  sensorValue = analogRead(sensorPin);

  // apply the calibration to the sensor reading
  sensorValue = map(sensorValue, sensorMin, sensorMax, 0, 255);

  // in case the sensor value is outside the range seen during calibration
  sensorValue = constrain(sensorValue, 0, 255);

  // fade the LED using the calibrated value:
  analogWrite(ledPin, sensorValue);
}

O conteúdo desta página é uma tradução para o português a partir do site original do Arduino.