Este exemplo mostra como filtrar o ruído de uma entrada, o que significa verificar duplamente em curto período de tempo para estar seguro que está realmente pressionado. Ele também filtra o sinal da entrada, sem a qual pressionando uma vez o botão, apareceria no código múltiplos acessos. Use a função millis() para obter a informação do momento em que o botão foi pressionado.

Componentes necessários:

  • Arduino
  • Botão
  • Resistor 10kΩ
  • Protoboard
  • Jumpers
  • 1 Cabo USB

Circuito

Arduino Exemplos: Filtrar o ruído

 

Conecte 3 jumpers à placa Arduino. Os dois primeiros, vermelho e preto, conecte às duas linhas verticais laterais da protoboard para prover acesso ao suprimento de 5 volts e terra. O terceiro jumper vai do pino digital 2 até uma perna do botão. Esta mesma perna do botão conecta um resistor (neste caso de 10kΩ) ao terra. A outra perna do botão conecta ao suprimento de 5 volts.

Quando o botão está aberto (não pressionado) não há conexão entre as duas saídas do botão, então o pino está conectado ao terra (através do resistor pull-up) e podemos ler um LOW. Quando o botão está fechado (pressionado) faz a conexão entre as saídas do botão e fazendo a conexão com 5 volts, e com isso podemos ler HIGH.

Esquema

 

Arduino Exemplos: Botão

Código

O código abaixo é baseado na versão de debounce de Limor Fried, só que de maneira invertida. No exemplo dela, o botão retorna LOW quando fechado e HIGH quando aberto. Neste exemplo, o botão retorna HIGH quando pressionado e LOW quando não.
/*
 Debounce
 
 Each time the input pin goes from LOW to HIGH (e.g. because of a push-button
 press), the output pin is toggled from LOW to HIGH or HIGH to LOW.  There's
 a minimum delay between toggles to debounce the circuit (i.e. to ignore
 noise).  
 
 The circuit:
 * LED attached from pin 13 to ground
 * pushbutton attached from pin 2 to +5V
 * 10K resistor attached from pin 2 to ground
 
 * Note: On most Arduino boards, there is already an LED on the board
 connected to pin 13, so you don't need any extra components for this example.
 
 
 created 21 November 2006
 by David A. Mellis
 modified 30 Aug 2011
 by Limor Fried
 modified 28 Dec 2012
 by Mike Walters
 
 This example code is in the public domain.
 
 http://www.arduino.cc/en/Tutorial/Debounce
 */


// constants won't change. They're used here to
// set pin numbers:
const int buttonPin = 2;    // the number of the pushbutton pin
const int ledPin = 13;      // the number of the LED pin

// Variables will change:
int ledState = HIGH;         // the current state of the output pin
int buttonState;             // the current reading from the input pin
int lastButtonState = LOW;   // the previous reading from the input pin

// the following variables are long's because the time, measured in miliseconds,
// will quickly become a bigger number than can be stored in an int.
long lastDebounceTime = 0;  // the last time the output pin was toggled
long debounceDelay = 50;    // the debounce time; increase if the output flickers

void setup() {
  pinMode(buttonPin, INPUT);
  pinMode(ledPin, OUTPUT);

  // set initial LED state
  digitalWrite(ledPin, ledState);
}

void loop() {
  // read the state of the switch into a local variable:
  int reading = digitalRead(buttonPin);

  // check to see if you just pressed the button
  // (i.e. the input went from LOW to HIGH),  and you've waited
  // long enough since the last press to ignore any noise:  

  // If the switch changed, due to noise or pressing:
  if (reading != lastButtonState) {
    // reset the debouncing timer
    lastDebounceTime = millis();
  }
 
  if ((millis() - lastDebounceTime) > debounceDelay) {
    // whatever the reading is at, it's been there for longer
    // than the debounce delay, so take it as the actual current state:

    // if the button state has changed:
    if (reading != buttonState) {
      buttonState = reading;

      // only toggle the LED if the new button state is HIGH
      if (buttonState == HIGH) {
        ledState = !ledState;
      }
    }
  }
 
  // set the LED:
  digitalWrite(ledPin, ledState);

  // save the reading.  Next time through the loop,
  // it'll be the lastButtonState:
  lastButtonState = reading;
}

O conteúdo desta página é uma tradução para o português a partir do site original do Arduino.